Microsoft Excel proporciona tres funciones diferentes para extraer en Excel texto de una longitud específica de una celda. Dependiendo de dónde desee comenzar la extracción, use una de estas fórmulas:
- Función IZQUIERDA: para extraer en Excel una subcadena de la izquierda.
- Función DERECHA: para extraer texto de la derecha.
- Función EXTRAE: para extraer una subcadena del medio de una cadena de texto, comenzando en el punto que especifique.
Como es el caso con otras fórmulas, las funciones de subcadena de Excel son mejores para aprender de un ejemplo, así que veamos algunas.
Extraer en excel subcadena desde el inicio de la cadena (IZQUIERDA)
Para extraer en excel texto de la izquierda de una cadena, utilice la función IZQUIERDA de Excel:
IZQUIERDA(texto, [num_caracteres])Donde texto es la dirección de la celda que contiene la cadena de origen y num_caracteres es la cantidad de caracteres que desea extraer.
Por ejemplo, para obtener los primeros 3 caracteres desde el principio de una cadena de texto, use esta fórmula:
=IZQUIERDA(A2,3)
Obtener subcadena desde el final de la cadena (DERECHA)
Si deseo extraer en Excel una subcadena de la parte derecha de una cadena de texto, utilice la función DERECHA de Excel:
DERECHA(texto, [num_caracteres])Por ejemplo, para obtener los últimos 4 caracteres del final de una cadena, use esta fórmula:
=DERECHA(A2,4)
Extraer en excel texto de la mitad de la cadena
Si está buscando extraer en Excel una subcadena que comience en el medio de una cadena, en la posición que especifique, entonces Extrae es la función en la que puede confiar.
En comparación con las otras dos funciones de texto, Extrae en Excel tiene una sintaxis ligeramente diferente:
Extrae(texto, núm_inicio, núm_caracteres)Además de text (la cadena de texto original) y num_caracteres (la cantidad de caracteres a extraer), también indica núm_inicio (el punto de partida).
En nuestro conjunto de datos de muestra, para obtener tres caracteres desde el medio de una cadena que comienza con el sexto carácter, usa la siguiente fórmula:
=Extrae(A2,6,3)
Consejo. El resultado de las fórmulas Derecha, Izquierda y Extrae siempre es texto, incluso cuando está extrayendo un número de una cadena de texto . Si desea operar en el resultado como un número , ajuste su fórmula en la función VALOR de esta manera:=VALUE(Extrae(A2,6,3))
Extraer subcadena antes o después de un carácter dado
Como se muestra en los ejemplos anteriores, las funciones IZQUIERDA, DERECHA y EXTRAE funcionan muy bien con cadenas uniformes. Cuando se trata de cadenas de texto de longitud variable, se necesitarán manipulaciones más complejas.
Nota. La función Buscar no distingue entre mayúsculas y minúsculas para obtener la posición de un carácter. Si desea una fórmula que distinga entre mayúsculas y minúsculas , utilice la función encontrar en su lugar.
Cómo extraer texto en Excel antes de un carácter específico
Para obtener una subcadena que preceda a un carácter dado, se deben hacer dos cosas: primero, determina la posición del carácter de interés y luego extrae todos los caracteres anteriores. Más precisamente, usa la función ENCONTRAR para encontrar la posición del carácter y resta 1 del resultado, porque no desea incluir el carácter en sí mismo en la salida. Y luego, envía el número devuelto directamente al argumento num_caracteres de la función IZQUIERDA:
IZQUIERDA( celda , ENCONTRAR(" caracter ", celda )-1)Por ejemplo, para extraer una subcadena antes del carácter de guion (-) de la celda A2, use esta fórmula:
=IZQUIERDA(A2, ENCONTRAR("-",A2)-1)No importa cuántos caracteres contenga su cadena de Excel, la fórmula solo extrae el texto antes del primer guion:
Cómo extraer texto en Excel después de carácter
Para obtener texto después de un carácter específico, utilice un enfoque ligeramente diferente: obtenga la posición del carácter con BUSCAR o ENCONTRAR, reste ese número de la longitud total de la cadena devuelta por la función LARGO y extraiga esa cantidad de caracteres del final de la cuerda.
DERECHA( celda ,LARGO( celda )-ENCONTRAR(" CARACTER", celda ))En nuestro ejemplo, usaríamos la siguiente fórmula para extraer una subcadena después del primer guión:
=DERECHA(A2,LARGO(A2)-ENCONTRAR("-",A2))
Cómo extraer texto entre dos instancias de un carácter
Para obtener una subcadena entre dos ocurrencias de un determinado carácter, use la siguiente fórmula genérica:
EXTRAE( celda , ENCONTRAR(" caracter", celda )+1, ENCONTRAR(" caracter ", celda , ENCONTRAR (" caracter " , celda )+1) - ENCONTRAR (" caracter ", celda )-1)Los dos primeros argumentos de esta fórmula EXTRAE son muy claros:
Texto es la celda que contiene la cadena de texto original.
inicio_num (punto de inicio): una fórmula de ENCONTRAR simple devuelve la posición del carácter deseado, al que agrega 1 porque desea comenzar la extracción con el siguiente carácter.
Num_caracteres (número de caracteres para extraer) es la parte más complicada:
- Primero, calcula la posición de la segunda aparición del carácter anidando una función de búsqueda dentro de otra.
- Después de eso, resta la posición de la primera ocurrencia de la posición de la segunda ocurrencia y resta 1 del resultado ya que no desea incluir el carácter delimitador en la subcadena resultante.
Por ejemplo, para extraer texto rodeado por dos guiones, usaría esta fórmula:
=EXTRAE(A2, ENCONTRAR("-",A2) + 1, ENCONTRAR
("-",A2,ENCONTRAR("-",A2)+1) - ENCONTRAR("-",A2) - 1)La siguiente captura de pantalla muestra el resultado:
